Инструкционно-технологическая карта

Практическая работа

|  |
| --- |
| **Тема: «**Работа с текстовыми функциями**»** |
| **Цель работы:** | научиться обрабатывать текст в процессе решения задач в MS Excel. |
| **Оборудование:** | инструкционно-технологическая карта практической работы, ПК, набор необходимого программного обеспечения |

***Ход работы***

1. Прочитать теоретический материал.
2. Выполнить задание.
3. Составить отчет по выполненной работе.
4. Сдать преподавателю и защитить отчет.

**Теоретический материал**

**дополнительный материал по ссылке:** [**https://resh.edu.ru/subject/lesson/5817/main/82481/**](https://resh.edu.ru/subject/lesson/5817/main/82481/)

[**https://www.youtube.com/watch?v=JNPXnu96NCw**](https://www.youtube.com/watch?v=JNPXnu96NCw)

**Обратная связь:** **cheerful-29@yandex.ru**

* помощью функций обработки текста можно выполнять различные преобразования над строковыми данными.В Microsoft Excel имеется 24 функции, относящихся к данной группе. Рассмотрим использование некоторых из них при решении различных задач, часто возникающих в практической деятельности:

**СЦЕПИТЬ (текст1; текст2; …)** –объединяет несколько текстовых строк в одну.

**СЖПРОБЕЛЫ** (**текст**) –удаляет из текста лишние пробелы(кроме одиночных пробеловмежду словами).

**ЛЕВСИМВ (текст;кол\_зн)** –возвращает указанное количество знаков с начала строкитекста.

**НАЙТИ (строка;текст; поз)** –возвращает номер позиции первого вхождения строки втекст, начиная с указанной позиции. Нумерация ведется относительно левого символа текста.

**ДЛСТР(текст)** –возвращает количество знаков в текстовой строке.

**ПРАВСИМВ(текст;кол\_зн)** –возвращает указанное количество знаков с конца строкитекста.

**ПСТР ( текст; поз; кол\_зн)** –возвращает заданное количество знаков из строки текста,начиная с указанной позиции.

**ЗАМЕНИТЬ (текст; поз; кол\_зн; строка)** –заменяет в тексте начиная с указаннойпозиции заданное количество символов на другую строку.

**ПРАКТИЧЕСКАЯ ЧАСТЬ**

**Задача 1. У классного руководителя есть список учащихся класса в следующем виде**

|  |  |  |  |
| --- | --- | --- | --- |
|  | A | B | C |
| 1 | Агеев | Андрей | Иванович |
| 2 | … | … | … |
| 3 | Яковлев | Яков | Яковлевич |

Но ему нужно представить список несколько в другом виде, объединив фамилию, имя и отчество в одной ячейке:

|  |  |  |  |
| --- | --- | --- | --- |
|  | A | B | C |
| 1 | Агеев Андрей Иванович |  |  |
| 2 | … |  | … |
| 3 | Яковлев Яков Яковлевич |  |  |

Решение.

Эта задача легко решается с помощью одной функции СЦЕПИТЬ. Выделив ячейку D1, с помощью Мастера функций в категории Текстовые выбираем эту функцию и заполняем

нужные поля следующим образом (адреса ячеек вводятся автоматически, если щелкнуть мышью по соответствующей клетке в таблице; кавычки набирать не нужно, они также появятся автоматически после ввода пробела и перехода к следующему полю!)



Осталось только растянуть формулу на нужное количество строк. В столбце D список получен . Правда, если удалить столбцы А:С, то список «разрушится», вместо нужных данных, в столбце появятся ошибочные значения #ССЫЛКА! – мы удалили ячейки, на которые были ссылки в формулах. Чтобы такого не произошло, нужно сначала получить новый список в ячейках в виде значений (а не формул). Для этого нужно выделить столбец D и скопировать его (в буфер). Затем выделить нужный столбец, диапазон или верхнюю ячейку диапазона и в меню Правка выбрать пункт Специальная вставка. В открывшемся окне выбрать радиокнопку Значения и нажать ОК.

В выбранном диапазоне формулы заменятся на значения и полученный список может «существовать» совершенно независимо от исходного.

**Задача 2.Необходимо получить из списка**

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
|  | A |  | B | C |
| 1 | Фамилия | Имя | Отчество |
| 2 | Агеев | Андрей | Иванович |
| 3 | … | … | … |
| 4 | Яковлев | Яков | Яковлевич |
| список фамилий с инициалами: |  |
|  |  |  |  |  |
|  | A |  | B | C |
| 1 | Фамилия И.О. |  |  |  |
| 2 | Агеев А.И. |  |  |  |
| 3 | … |  |  | … |
| 4 | Яковлев Я.Я. |  |  |  |

**Решение.**

Выполним поставленную задачу последовательно . Сначала в ячейку D1 внесем формулу с функцией, которая выделяет первый символ из имени. Для этого с помощью Мастера функций в категории Текстовые выберем функцию ЛЕВСИМВ (рекомендуется в практической работе и дальше все функции вставлять в формулы с использованием Мастера функций).



После сохранения формулы в ячейке D1 скопируем ее в ячейку E1 для выделения первого символа отчества. А затем с помощью функции СЦЕПИТЬ объединим нужные ячейки, пробел и точки.

* помощью копирования и специальной вставки сохраним полученный список в виде значений в нужном диапазоне.

**Задача 3 (обратная задаче 1).**

Из имеющегося списка

|  |  |  |  |
| --- | --- | --- | --- |
|  | A | B | C |
| 1 | Агеев Андрей Иванович |  |  |
| 2 | … |  | … |
| 3 | Яковлев Яков Яковлевич |  |  |

нужно получить список, в котором фамилии имена и отчества расположены в отдельных ячейках.

|  |  |  |  |
| --- | --- | --- | --- |
|  | A | B | C |
| 1 | Фамилия | Имя | Отчество |
| 2 | Агеев | Андрей | Иванович |
| 3 | … | … | … |
| 4 | Яковлев | Яков | Яковлевич |

**Решение.**

При решении данной задачи будем считать, что между фамилией, именем и отчеством стоят ровно по одному пробелу. Если это не так, сначала приведем исходный список к такой структуре. Чтобы не усложнять задачу, будем выполнять действия последовательно,

записывая в отдельные ячейки промежуточные результаты расчетов с использованием различных функций:

1. В ячейку В1 – формулу, позволяющую удалить лишние пробелы. = СЖПРОБЕЛЫ(А1)
2. в ячейку С1 – формулу, позволяющую найти позицию первого пробела
3. =НАЙТИ(" ";B1) – третий параметр не указан, т.к. ищем первое вхождение пробела от начала строки.
4. В ячейку D1 – формулу, позволяющую найти позицию второго пробела (между именем и отчеством)
5. =НАЙТИ(" ";B1;C1+1) – здесь третий параметр указывает, что поиск ведется со следующего символа от найденного в С1 пробела.
6. В ячейку E1 – формулу для определения общего количества символов в фамилии, имени и отчестве, включая два пробела.
7. =ДЛСТР(B1)
8. В ячейку F1 – формулу для выделения фамилии. Воспользуемся уже знакомой функцией. =ЛЕВСИМВ(B1;C1-1)
9. Ячейку пока пропустим.
10. В ячейку H1 – формулу для выделения отчества. Отчество расположено в конце строки, поэтому воспользуемся функцией ПРАВСИМВ, а количество выделяемых символов легко найдем, зная номер позиции пробела перед отчеством и общую длину строки. =ПРАВСИМВ(B1;E1-D1)
11. В ячейку G1 – формулу для выделения имени. Имя расположено внутри строки между пробелами, позиции которых мы уже вычислили. Для его выделения воспользуемся функцией
12. =ПСТР(B1;C1+1;D1-C1-1)
13. С помощью копирования и специальной вставки сохраним полученный список в виде значений.

**Задача 4**.Из имеющегося списка

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
|  | A |  | B |  | C |
| 1 | Агеев Андрей Иванович |  |  |  |  |  |
| 2 | … |  |  |  |  | … |
| 3 | Яковлев Яков Яковлевич |  |  |  |  |  |
| нужно получить список фамилий с инициалами |  |  |
|  |  |  |  |  |  |
|  | A | B |  |  | C |
| 1 | Агеев А.И. |  |  |  |  |  |
| 2 | … |  |  |  | … |
| 3 | Яковлев Я.Я. |  |  |  |  |  |

Решите данную задачу самостоятельно, используя изученные функции.

**Задача 5. У секретаря учебной части имеется список учащихся выпускного класса в следующем виде:**

|  |  |  |  |
| --- | --- | --- | --- |
|  | A | B | C |
| 1 | Агеев | Андрей | Иванович |
| 2 | … | … | … |
| 3 | Яковлев | Яков | Яковлевич |

Для печати аттестатов нужно получить аналогичный список учащихся в дательном падеже. Конечно, можно вручную изменять окончания в каждой ячейке, но если выпускников много, то это длительный процесс. Помогите автоматизировать эту работу, переведя в дательный падеж по возможности большую часть имеющихся фамилий, имен и отчеств, используя возможности Excel.

Решение.

Конечно, очень трудно определить все возможные типы фамилий, имен и отчеств, встречающиеся у российских граждан, поэтому определим как меняются окончания в наиболее типичных фамилиях и именах в именительном и дательном падежах. Так как в русском языке склонение существительных и прилагательных различаются в мужском и женском роде, то и основные типы женских и мужских фамилий и имен представим в отдельных таблицах.

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Женские фамилии в | Женские фамилии в |  | Женские фамилии в | Женские фамилии |  |
| именительном падеже | дательном падеже |  | именительном | в дательном |  |
|  |  |  | падеже | падеже |  |
| На -ова, -ева, -ина: | Петров**ой**, Агеев**ой**, |  | На -ия : | Мар**ии** |  |
| Петров**а**, Агеев**а**, Катин**а** | Катин**ой** |  | Мар**ия** |  |
| На -ая: |  |  | На -ья: | Дар**ье** |  |
| Римск**ая**, Оболонн**ая** | Римск**ой,** Оболонн**ой** |  | Дар**ья** |  |
| На -о: | Хомченко |  | На согласные: | Мариам, Дениз |  |
| Хомченко |  | Мариам, Дениз |  |
| На -а: Водяха | Водяха |  | На -а: Татьян**а** | Татьян**е** |  |
| На -ь: Козарь | Козарь |  | На -ь: Нинел**ь** | Нинел**и** |  |
| На -ик: Бублик | Бублик |  |  |  |  |
| На -ых: Пьяных | Пьяных |  |  |  |  |

В женском отчестве на -овна или -евна в дательном падеже буква «а» заменяется на «е».

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| Мужские фамилии в | Мужские фамилии в |  | Мужские имена | Мужские имена в |  |
| именительном падеже | дательном падеже |  | в именительном | дательном падеже |  |
|  |  |  | падеже |  |  |
| На -**ов**, -**ев**, -**ин**: | Петров**у**, Агеев**у**, Катин**у** |  | На -ей, -ий: | Серге**ю**, Дмитри**ю** |  |
| Петров, Агеев, Катин |  |  | Серге**й**, Дмитри**й** |  |
| На -**о**: Хомченко | Хомченко |  | На -я: Иль**я** | Иль**е** |  |
| На -**ий,** -**ый**: |  |  | На согласные: | Глеб**у**, Иван**у** |  |
| Римск**ий,** Оболонн**ый** | Римск**ому,** Оболонн**ому** |  | Глеб, Иван |  |
| На -**а**: Водях**а** | Водях**е** |  | На -а: Никит**а** | Никит**е** |  |
| На -ь: Козар**ь** | Козар**ю** |  | На -ь: Игорь | Игор**ю** |  |
| На -ик: Бублик | Бублик**у** |  |  |  |  |
| На -ых: Пьяных | Пьяных |  |  |  |  |

К мужскому отчеству на -ович или -евич в дательном падеже добавляется буква «у».

Чтобы не слишком усложнять формулы для перевода фамилий, имен и отчеств из именительного в дательный падеж, следует разделить списки по полу, и сделать преобразования для каждого списка по-отдельности. Будет проще, если в соседнем с отчеством столбце добавить соответственно символы «ж» и «м» и отсортировать список по этому столбцу. Затем скопировать каждую часть списка на отдельные листы ЭТ.

Начнем преобразование с женских фамилий. Из таблицы видно, что если фамилия оканчивается на «ая», то эти две буквы нужно заменить на «ой», если на «ва» или «на», то на «ой» нужно заменить только последнюю букву «а». В остальных случаях фамилия не изменяется.

Если все выделения букв, проверки и замены учесть в одной формуле, она будет слишком громоздкой, поэтому в ячейках D1: G1 выполним промежуточные действия.

|  |  |  |
| --- | --- | --- |
|  | Формула | Пояснение |
| D1 | =ДЛСТР(A1) | количество символов в фамилии (длину строки) |
| E1 | =ПРАВСИМВ(A1;2) | две последние буквы фамилии |
| F1 | =ЗАМЕНИТЬ(A1;D1-1;2;"ой") | замена двух последних букв в фамилии |
| G1 | =ЗАМЕНИТЬ(A1;D1;1;"ой") | замена одной последней буквы в фамилии |

Тогда в ячейке H1 из этих частей фамилия в дательном падеже будет сформирована с помощью следующей формулы:

=ЕСЛИ(E1="ая";F1;ЕСЛИ(ИЛИ(E1="ва";E1="на");G1;A1))

Преобразование женских имен выполним другим способом – выделяя часть имени и сцепляя с нужными окончаниями. В ячейках I1: L1 выполним промежуточные действия

|  |  |  |
| --- | --- | --- |
| Ячейка | Формула | Пояснение |
| I1 | =ДЛСТР(B1) | количество символов в имени (длина строки) |
| J1 | =ПРАВСИМВ(B1;1) | последняя буква имени |
| K1 | =ЛЕВСИМВ(B1;I1-1) | часть имени без последней буквы |
| L1 | =ПРАВСИМВ(B1;2) | две последние буквы имени |

В ячейке М1 имя может быть сформировано следующей формулой:

=ЕСЛИ(ИЛИ(J1="а";L1="ья");СЦЕПИТЬ(K1;"е");ЕСЛИ(L1="ия";СЦЕПИТЬ(K1;"и");B1))

* ячейке N1 сформируем дательный падеж отчества: =ЗАМЕНИТЬ(C1;ДЛСТР(C1);1;"е")

Теперь выделим диапазон всех заполненных ячеек D1:N1 и скопируем (растяним) их на весь список. Сохраним столбцы с полученными фамилиями, именами и отчествами как значения в нужном диапазоне на этом же или другом листе электронной таблицы.

Преобразование мужских фамилий несколько сложнее, так как нужно учесть большее количество вариантов. Поэтому выполним промежуточные действия.

|  |  |  |
| --- | --- | --- |
| Ячейка | Формула | Пояснение |
| D1 | =ДЛСТР(A1) | количество символов в фамилии |
| E1 | =ПРАВСИМВ(A1) | последняя буква фамилии |
| F1 | =ПРАВСИМВ(A1;2) | две последние буквы фамилии |
| G1 | =ЛЕВСИМВ(A1;D1-1) | часть фамилии без последней буквы |

* следующих ячейках в каждой формуле будем не только проводить вычисления с помощью различных функций для всех типов фамилий, но в каждой ячейке будем формировать фамилии определенных типов, при этом последовательно объединяя их. Это будет особенно наглядно, когда формулы будут скопированы на весь список. Например, в ячейке Н1 запишем формулу для формирования дательного падежа фамилий с окончанием на «а» и «ь», в ячейке I1 – для фамилий с окончанием на «ий» и «ый», в ячейке J1- учтем фамилии с окончанием на «ых» и «ко» (они не изменяются), а в ячейке К1 добавим остальные типы мужских фамилий, у которых в дательном падеже появляется окончание «у».

|  |  |
| --- | --- |
| H1 | =ЕСЛИ(E1="а";СЦЕПИТЬ(G1;"е");ЕСЛИ(E1="ь";СЦЕПИТЬ(G1;"ю");"")) |
| I1 | =ЕСЛИ(ИЛИ(F1="ий";F1="ый");ЗАМЕНИТЬ(A1;D1-1;2;"ому");H1) |
| J1 | =ЕСЛИ(ИЛИ(F1="ых";F1="ко");A1;I1) |
| K1 | =ЕСЛИ(J1<>"";J1;СЦЕПИТЬ(A1;"у")) |

В следующих ячейках сформируйте самостоятельно имена и отчества.

**КОНТРОЛЬНЫЕ ВОПРОСЫ**

1. Каким способом в Excel можно соединить 2 или более строки?
2. В чем заключается отличие функции ЗАМЕНИТЬ() от функции ПОДСТАВИТЬ()?
3. В чем заключается отличие функции НАЙТИ() от функции ПОИСК()?
4. Какая функция позволяет избавиться от лишних пробельных символов?